1

Тема: Gnuplot

Якщо хтось користується Gnuplot, підкажіть як в підпису осі зображати степені, паприклад s^{-1} ?

2

Re: Gnuplot

Спочатку оберіть правильний термінал:

set term postscript enhanced color

Потім зображуйте степені:

set xlabel "x^{15}"

Або так:

set xlabel "x**15"

Якщо треба - конвертуйте у потрібний вам формат

convert picture.ps picture.png
Говорила баба діду: «Я поїду к Білодіду, Ізучу двомовну мову І вернусь обратно знову». А дід бабі: «Не *изди, К Білодіду нєт їзди, — Туди не ходять поїзди»
Подякували: dialectstat1

3

Re: Gnuplot

0xDADA11C7 написав:

Спочатку оберіть правильний термінал:

set term postscript enhanced color

Потім зображуйте степені:

set xlabel "x^{15}"

Або так:

set xlabel "x**15"

Якщо треба - конвертуйте у потрібний вам формат

convert picture.ps picture.png

Величезне дякую!
Це були проблеми якраз з терміналом, тепер все працює.

І ще питання, як зробити щоб підписи осей були зі степеннями, а не 1Е-15, 1Е-16?
Де можна знайти список кодів для ліній різний типів, мене цікавить задавання типу (суцільна, пунктирна, штрихпунктира і т.д. та їхнього кольору)?

4

Re: Gnuplot

http://gnuplot.sourceforge.net/demo/dashcolor.1.png

#
# Demonstrate explicit choice of both dot/dash pattern (linetype) and color (linecolor).
#
set termoption dash

set xrange [-0.5:3.5]
set yrange [-1:1.4]
set bmargin 7
unset ytics
unset xtics
#
set title "Independent colors and dot/dash styles"
unset colorbox
#
# define line styles using explicit rgbcolor names
#
set style line 1 lt 2 lc rgb "red" lw 3
set style line 2 lt 2 lc rgb "orange" lw 2
set style line 3 lt 2 lc rgb "yellow" lw 3
set style line 4 lt 2 lc rgb "green" lw 2
#
set label 1 'set style line 1 lt 2 lc rgb "red" lw 3'    at -0.4, -0.25 tc rgb "red"
set label 2 'set style line 2 lt 2 lc rgb "orange" lw 2' at -0.4, -0.35 tc rgb "orange"
set label 3 'set style line 3 lt 2 lc rgb "yellow" lw 3' at -0.4, -0.45 tc rgb "yellow"
set label 4 'set style line 4 lt 2 lc rgb "green" lw 2'  at -0.4, -0.55 tc rgb "green"
set label 5 'plot ... lt 1 lc 3 ' at -0.4, -0.65 tc lt 3
set label 6 'plot ... lt 3 lc 3 ' at -0.4, -0.75 tc lt 3
set label 7 'plot ... lt 5 lc 3 ' at -0.4, -0.85 tc lt 3
#
set xlabel "You will only see dashed lines if your current terminal setting permits it"
#
show style line
#
# draw some plots
#
plot cos(x)     ls 1 title 'ls 1',   \
     cos(x-.2)  ls 2 title 'ls 2',\
     cos(x-.4)  ls 3 title 'ls 3',\
     cos(x-.6)  ls 4 title 'ls 4', \
     cos(x-.8)  lt 1 lc 3 title 'lt 1 lc 3',  \
     cos(x-1.)  lt 3 lc 3 title 'lt 3 lc 3',  \
     cos(x-1.2) lt 5 lc 3 title 'lt 5 lc 3'
#

Звідсіля

Приклади використання специфікаторів формату:

     
     set format y "%t"; set ytics (5,10)          # "5.0" and "1.0"
     set format y "%s"; set ytics (500,1000)      # "500" and "1.0"
     set format y "%+-12.3f"; set ytics(12345)    # "+12345.000  "
     set format y "%.2t*10^%+03T"; set ytic(12345)# "1.23*10^+04"
     set format y "%s*10^{%S}"; set ytic(12345)   # "12.345*10^{3}"
     set format y "%s %cg"; set ytic(12345)       # "12.345 kg"
     set format y "%.0P pi"; set ytic(6.283185)   # "2 pi"
     set format y "%.0f%%"; set ytic(50)          # "50%"

Повний перелік знаходиться тут

Говорила баба діду: «Я поїду к Білодіду, Ізучу двомовну мову І вернусь обратно знову». А дід бабі: «Не *изди, К Білодіду нєт їзди, — Туди не ходять поїзди»
Подякували: dialectstat1

5

Re: Gnuplot

0xDADA11C7, дуже дякую, нарешті розібрався.