Граф = array(
  object(array("Флаг", 0), array("Имя", "Трусы"), array("Следующий", array("Ботинки", "Штаны"))),
  object(array("Флаг", 0), array("Имя", "Штаны"), array("Следующий", array("Ботинки", "Ремень"))),
  object(array("Флаг", 0), array("Имя", "Ремень"), array("Следующий", array("Пиджак"))),
  object(array("Флаг", 0), array("Имя", "Рубашка"), array("Следующий", array("Ремень", "Галстук"))),
  object(array("Флаг", 0), array("Имя", "Галстук"), array("Следующий", array("Пиджак"))),
  object(array("Флаг", 0), array("Имя", "Носки"), array("Следующий", array("Ботинки"))),
  object(array("Флаг", 0), array("Имя", "Ботинки"), array("Следующий", array())),
  object(array("Флаг", 0), array("Имя", "Часы"), array("Следующий", array())),
  object(array("Флаг", 0), array("Имя", "Пиджак"), array("Следующий", array()))
);

Итоговый список = array();

function Поиск в глубину(Узел) {
  Узел.Флаг = 1;
  local Список смежности = Узел.Следующий;
  while(i <= alen(Список смежности)) begin local i = 1; step i = i + 1; {
    local Имя смежного узла = Список смежности[i];
    while(j <= alen(Граф)) begin local j = 1; step j = j + 1; {
      local Смежный узел = Граф[j];
      if(Смежный узел.Имя = Имя смежного узла) {
        do case {
          case(Смежный узел.Флаг = 1) {
            print "Найден цикл. Сортировка невозможна."; print; exit();
          }
          case(Смежный узел.Флаг = 0) {
            Поиск в глубину(Смежный узел); break;
          }
        }
      }
    }
  }
  Узел.Флаг = 2;
  aunshift(Итоговый список, Узел.Имя);
}
while(i <= alen(Граф)) begin i = 1; step i = i + 1; {
  Узел = Граф[i];
  if(Узел.Флаг = 0) {
    Поиск в глубину(Узел);
  }
}
print Итоговый список;

Массив #47 [9] {
  [1] => Часы (Строка)
  [2] => Носки (Строка)
  [3] => Рубашка (Строка)
  [4] => Галстук (Строка)
  [5] => Трусы (Строка)
  [6] => Штаны (Строка)
  [7] => Ремень (Строка)
  [8] => Пиджак (Строка)
  [9] => Ботинки (Строка)
}