unit MainUnit;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls,
  System.Generics.Collections, Vcl.ComCtrls;

type
  TMainForm = class(TForm)
    SourceMemo: TMemo;
    DisplayMemo: TMemo;
    Splitter1: TSplitter;
    BottomPanel: TPanel;
    Quest1Button: TButton;
    Quest2Button: TButton;
    Quest3Button: TButton;
    InsertSourceButton: TButton;
    CopyResultButton: TButton;
    ProgressBar1: TProgressBar;
    Label1: TLabel;
    TimeLabel: TLabel;
    procedure Quest2ButtonClick(Sender: TObject);
    procedure InsertSourceButtonClick(Sender: TObject);
    procedure CopyResultButtonClick(Sender: TObject);
    procedure Quest1ButtonClick(Sender: TObject);
    procedure Quest3ButtonClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    StartTime: Integer;

    procedure InitCalc;
    procedure FinalizeCalc;

    procedure EnabledControl(AEnable: Boolean);
    { Private declarations }
  public
    { Public declarations }
  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

resourcestring
  StrFormat = 'Case #%d: %s';

const
  BoolLabel: array [Boolean] of string = ('NO', 'YES');

function ParseInt(S: string): TArray<Integer>;
var
  P, P2: PChar;
begin
  P := PChar(S);
  SetLength(Result, 0);

  while P^ <> #0 do
  begin
    while not CharInSet(P^, ['0'..'9'])  do
      Inc(P);
      
    P2 := P;
    while CharInSet(P^, ['0'..'9']) do
      Inc(P);

    if Integer(P2) < Integer(P) then
    begin    
      SetLength(Result, Length(Result) + 1);
      Result[High(Result)] := StrToInt(Copy(P2, 0, P - P2));
    end;
  end;
end;

procedure TMainForm.CopyResultButtonClick(Sender: TObject);
begin
  DisplayMemo.SelectAll;
  DisplayMemo.CopyToClipboard;
end;

procedure TMainForm.InsertSourceButtonClick(Sender: TObject);
begin
  SourceMemo.Clear;
  SourceMemo.PasteFromClipboard;
end;

procedure TMainForm.EnabledControl(AEnable: Boolean);
begin
  Quest1Button.Enabled := AEnable;
  Quest2Button.Enabled := AEnable;
  Quest3Button.Enabled := AEnable;
  InsertSourceButton.Enabled := AEnable;
  CopyResultButton.Enabled := AEnable;
end;

procedure TMainForm.FinalizeCalc;
begin
  DisplayMemo.Lines.EndUpdate;
  EnabledControl(True);
  TimeLabel.Caption := IntToStr(GetTickCount - StartTime);
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  {$IFDEF DEBUG} MainForm.Caption := MainForm.Caption + ' (DEBUG)'; {$ENDIF}
end;

procedure TMainForm.InitCalc;
begin
  DisplayMemo.Lines.Clear;
  DisplayMemo.Lines.BeginUpdate;
  ProgressBar1.Max := StrToInt(SourceMemo.Lines[0]);
  StartTime := GetTickCount;
  EnabledControl(False);
end;

procedure TMainForm.Quest1ButtonClick(Sender: TObject);

  function NiceOfStr(S: string): Integer;
  var
    C: Char;
    CharsCount: array [1..26] of Integer;
    I: Integer;
  begin
    S := AnsiLowerCase(S);
    Result := 0;
    for I := 1 to 26 do CharsCount[i] := 0;      
    for C in S do
      if CharInSet(C, ['a'..'z']) then
        Inc(CharsCount[Ord(C) - Ord('a') + 1]);

    TArray.Sort<Integer>(CharsCount);
    for I := 1 to 26 do
      Inc(Result, CharsCount[i] * I);
  end;

var
  I: Integer;
begin
  InitCalc;
  with SourceMemo do
  try
    for I := 1 to Lines.Count - 1 do
    begin
      DisplayMemo.Lines.Add(Format(StrFormat,
        [I, IntToStr(NiceOfStr(Lines[i]))]));
      ProgressBar1.Position := I;
      Application.ProcessMessages;
    end;
  finally
    FinalizeCalc;
  end;
end;

procedure TMainForm.Quest2ButtonClick(Sender: TObject);

  function IsBalanc(PText: PChar; Opened: Integer = 0): Boolean;
  begin
    while PText^ <> #0 do
    begin
      if (PText[0] = ':') and (CharInSet(PText[1], ['(', ')'])) then
        Exit(IsBalanc(PChar(PText + 1), Opened)           // це дужка
        or IsBalanc(PChar(PText + 2), Opened));         // це смайлик

      case PText^ of
      '(' : Inc(Opened);
      ')' : Dec(Opened);
      else end;
      if Opened < 0 then Exit(False);
      Inc(PText);
    end;
    Result := Opened = 0;
  end;

var
  I: Integer;
begin
  InitCalc;
  with SourceMemo do
  try
    for I := 1 to Lines.Count - 1 do
    begin
      DisplayMemo.Lines.Add(Format(StrFormat,
        [I, BoolLabel[IsBalanc(PChar(Lines[i]))]]));
      ProgressBar1.Position := I;
      Application.ProcessMessages;
    end;
  finally
    FinalizeCalc;
  end;
end;

procedure TMainForm.Quest3ButtonClick(Sender: TObject);

  function GetItem(n, k, a, b, c, r: Int64): Int64;

    function InitM(Ak: Int64): TArray<Int64>;
    var
      I: Integer;
    begin
      SetLength(Result, Ak);
      Result[0] := a;
      for I := 1 to Ak -1 do
        Result[i] := (b * Result[I -1] + c) mod r;
    end;

    function GetFreeNumbers(Arr: TArray<Int64>): TArray<Boolean>;
    var
      I: Integer;
    begin
      SetLength(Result, Length(Arr) + 1);  //k + 1;
      for I := 0 to High(Result) do
        Result[i] := True;

      for I := High(Arr) downto 0 do    // ігноруємо дублі
        if Arr[i] <= High(Result) then
          if Result[Arr[i]] then
            Result[Arr[i]] := False
          else
            Arr[i] := MaxInt;
    end;

    function NextFree(Arr: TArray<Boolean>; var Start: Integer; Use: Boolean): Integer;
    var
      I: Integer;
    begin
      for I := Start to High(Arr) do
        if Arr[i] then
        begin
          if Use then
          begin
            Arr[i] := False;
            Start := I + 1;
          end
          else
            Start := I;
          Exit(I);
        end;
      Result := MaxInt;
    end;

  var
    m, X: TArray<Int64>;
    I: Integer;
    FreeNumbers: TArray<Boolean>;
    Start: Integer;
  begin
    m := InitM(k);
    FreeNumbers := GetFreeNumbers(m);
    SetLength(m, 2 * k + 1);

    Start := 0;
    m[k] := NextFree(FreeNumbers, Start, True);
    for I := k + 1 to High(m) do
      if m[I - k - 1] < Start then
        m[i] := m[I - k - 1]
      else
      begin
        if m[I - k - 1] <= k then
          FreeNumbers[m[I - k - 1]] := True;

        if m[I - k - 1] < NextFree(FreeNumbers, Start, False) then
          m[i] := m[I - k - 1]
        else
          m[i] := NextFree(FreeNumbers, Start, True);
      end;


    X := Copy(m, k, k + 1);
    Result := X[(n) mod (k + 1)];
  end;

var
  I: Integer;
begin
  InitCalc;
  with SourceMemo do
  try
    for I := 1 to (Lines.Count - 1) div 2 do
    begin
      DisplayMemo.Lines.Add(Format(StrFormat,
        [I, IntToStr(GetItem( ParseInt(Lines[I * 2 - 1])[0],
                              ParseInt(Lines[I * 2 - 1])[1],
                              ParseInt(Lines[I * 2])[0],
                              ParseInt(Lines[I * 2])[1],
                              ParseInt(Lines[I * 2])[2],
                              ParseInt(Lines[I * 2])[3]))]));
      ProgressBar1.Position := I;
      Application.ProcessMessages;
    end;
  finally
    FinalizeCalc;
  end;
end;

end.

5
4 3
3 6 2 8 
5 2
10 20 30 40 50 
6 4
0 1 2 3 5 8 
2 2
1069 1122 
10 5
10386 10257 10432 10087 10381 10035 10167 10206 10347 10088

Case #1: 30
Case #2: 400
Case #3: 103
Case #4: 1122
Case #5: 2621483

5
4 4 2 2 1 0 2 1 2 3 4
4 4 1 1 3 1 1 2 2 2 2
6 10 3 2 2 0 0 5 4 3 2
16 18 5 1 5 10 8 21 27 29 87
14 15 12 4 4 3 5 84 74 53 68

Case #1: 7
Case #2: 15
Case #3: 32
Case #4: 197
Case #5: 16